@echo off
: Gerard O'Rourke
: version 1.0
: Date 13/10/2017
SET IMPORTFILE=SystemTest.csv
SET CALLBACKFILTERFILES=SystemTest
SET LOGGERA=UCCE-RGR-A
SET IMPORTSHARE=\\%LOGGERA%\DialerImport\
SET CALLBACKFOLDER=C:\X-Callbacks\
SET CALLBACKFILTER=Callback
SET TEMPFILE=%CALLBACKFOLDER%\%CALLBACKFILTERFILES%-Temp.csv
: ***********************************************************************
:Check if Logger is up before Proceeding
REM One Ping First to get it in ARP Table in case it is not.
ping %LOGGERA% -n 1 >NUL
ping %LOGGERA% -n 1 | find "TTL" || goto LoggerDown
:Check if Files Exists Before Proceeding
IF EXIST %IMPORTSHARE%\%IMPORTFILE% goto ExitFileExists
IF EXIST %TEMPFILE% goto MoveFileToDialer
cd %CALLBACKFOLDER%
@echo Looping through Files and creating %TEMPFILE% ...
FOR %%i in (%CALLBACKFILTERFILES%*.txt) DO MOVE "%%i" "%%i.temp"
FIND "%CALLBACKFILTER%" %CALLBACKFILTERFILES%*.temp |find "%CALLBACKFILTER%" >%TEMPFILE%
DEL %CALLBACKFILTERFILES%*.txt.temp
REM Check if the file is empty first. if it is, delete it and exit.
FOR %%I in (%TEMPFILE%) do if %%~zI EQU 0 goto FileEmpty
:MoveFileToDialer
@echo Moving %TEMPFILE% to %IMPORTSHARE%\%IMPORTFILE%
MOVE %TEMPFILE% %IMPORTSHARE%\%IMPORTFILE%
@echo Pausing for 5 seconds before exit...
@ping 127.0.0.1 -n 5 >NUL
exit
:ExitFileExists
@echo File exists - do not continue.
@echo Pausing for 5 seconds before exit...
@ping 127.0.0.1 -n 5 >NUL
exit
:FileEmpty
DEL %TEMPFILE%
@echo File was empty - deleting empty file and exiting...
@echo Pausing for 5 seconds before exit...
@ping 127.0.0.1 -n 5 >NUL
exit
:LoggerDown
@echo Logger Server is Down so cannot continue, exiting...
@echo Pausing for 5 seconds before exit...
@ping 127.0.0.1 -n 5 >NUL
exit